Windows 7 Event Viewer Error "Failed to connect to the driver: (-2147024894)"

Do you know when this will be fixed? It currently logs this error once per second on the event log, which makes it very difficult to find any other useful information. If DropBox needs to log something as often as every second, it should perhaps only do it when a debug flag is set or perhaps to it's own log file somewhere.

Nick

Not sure whether cumulative update 6 for Windows 10 or the Dropbox v29.4.20 update caused it, but this issue is back with Windows 10. My Application event log is full of these generating one every second. This is pretty annyoing if you're trying to use the event log to for anything but useless dbxsvc events. The only work-around for now seems to be to stop the dbxsvc and set it to manual startup.

Screenshot: http://imgur.com/a/vLHXT

Installed in Nov... started the computer shutdowns.. uninstalled, no more shutdowns.  

I have office with 5 TB of space for less than $100 and get 5 installs of microsoft office with it... 

My entire experience with DB was really disappointing, having picked up the service for cheap in Nov... I was really happy.

Maybe loginmein will buy them and restore confidence in the company again.  Not sure how DB makes it with support like this.  

Are you sure that service DbxSvc is the culprit for producing an event "-2147024894" once per second?

On my Win7(x64) sytem I see this event at level "Information" (EventID 320) within the Application branch of the event log only once every time the DbxSvc service starts (that is after a system boot), and it always comes along with two other informational DbxSvc log entries: EventID 336 (Service started (1.0.22.0).) and EventID 258 (Pipe server thread started.)

(This is in reply to the accepted "solution" by a Dropboxer early in the thread.)

Now in 29.4.20, it logs similar "Failed to connect to the driver: -2147024894, retrying in 1000 milliseconds", *every second*.  This drowns out any useful events from other apps that I might try to troubleshoot.

Kester - apologies your posts didnt appear. They were for some reason picked up by spam filters. They are being a bit overzealous at the moment due to a mass influx of spam over the past few weeks. 

I've marked them all as none spam and they should show up shortly. 

Hi, I have had over 25,000 occurences of this event today, 7 July, 2017, in a little over six hours, so I believe it has to be having an effect on my system - which has crashed twice today.

Hi JCoady,

If you haven't already disabled DbxSvc, open the Windows Task Manager, open the Services tab, click the 'Services' button and then scroll down to 'DbxSvc' in the 'Services (Local) pane, right click 'DbxSvc', click 'Properties' and choose 'Disabled' in the 'Startup type' dropdown menu then click 'Apply'.

You should still be able to use Dropbox but the Event Viewer continuous logging of the driver problem should cease.

Hi again,

I created a workaround that consists of a task in the Windows task scheduler, that is triggered only if the well known unwanted event occurs (e.g. after a Dropbox update to the latest version, where the problem still isn't fixed).

If triggered, the task tries to "repair" the dbx driver in that it is configured to use dbx-stable.sys (if present) and to start automatically, so that the annoying per second events disappear, because afterwards the starting DbxSvc finds the running dbx driver to connect to.

Otherwise, if some set of conditions isn't met (e.g. if after a Dropbox update file dbx-stable.sys isn't present anymore), as an alternative workaround DbxSvc is simply stopped and its start type is set to disabled.

Here is how you can configure this workround (tested in Win7 x64, maybe that it must be adapted to other Windows systems):

First create some Folder, e.g. D:\CMD. Within this folder create a batch file named dbx.cmd

Open dbx.cmd (e.g. using notepad) and copy the following code to the file:

@echo off
SETLOCAL ENABLEDELAYEDEXPANSION

set ROOT=%~dp0
set LOG=%ROOT%dbx.log
call :clear "%LOG%"
echo Log for last execution: >>"%LOG%"
echo ----------------------- >>"%LOG%"
echo %DATE% %TIME% >>"%LOG%"
if not exist %windir%\System32\drivers\dbx.sys (
    echo File system32\DRIVERS\dbx.sys not found. >>"%LOG%"
    for /f "tokens=3" %%i in ('sc qc dbx ^| find "BINARY_PATH_NAME"') do (
        if /I "%%i"=="system32\DRIVERS\dbx.sys" (
            echo But file system32\DRIVERS\dbx.sys is referenced by Dropbox Mini-Filter Driver dbx^^! >>"%LOG%"
            call :svc DbxSvc stop
            if "!RETURN!"=="FALSE" (
                goto :EOF
            )
            if exist %windir%\System32\drivers\dbx-stable.sys (
                echo File dbx-stable.sys exists, trying to fix Dropbox Mini-Filter Driver dbx: >>"%LOG%"
                call :svc dbx stop
                if "!RETURN!"=="FALSE" goto :EOF
                sc config dbx start= auto binPath= system32\DRIVERS\dbx-stable.sys >nul
                echo Changing parameters of Dropbox Mini-Filter Driver dbx: >>"%LOG%"
                echo      Setting ImagePath to System32\drivers\dbx-stable.sys >>"%LOG%"
                echo      Setting Start type to auto >>"%LOG%"
                call :svc dbx start
                if "!RETURN!"=="FALSE" goto :EOF
                call :svc DbxSvc start
                if "!RETURN!"=="FALSE" goto :EOF
            ) else (
                sc config DbxSvc start= disabled >nul
                echo File dbx-stable.sys doesn't exist, disabling service DbxSvc:  >>"%LOG%"
                echo      Setting Start type to disabled >>"%LOG%"
            )
        )
    )
)
goto end

rem - function :clear (file)
rem   Deletes "file", if present.
:clear
if exist %1 del /f %1
goto :EOF

rem - function :svc (service, start|stop)
rem   Break, if "service" is in a pending state (neither stopped nor running)
rem   "stop": If running, try stopping "service", break if "service" hasn't stopped after 10 seconds.
rem   "start": If stopped, try starting "service", break if "service" isn't running after 10 seconds.
:svc
if "%2"=="stop" (
    set beginstate=4
    set finalstate=1
) else if "%2"=="start" (
    set beginstate=1
    set finalstate=4
)
for /f "tokens=3" %%i in ('sc query %1 ^| find "STATE"') do (
    if "%%i"=="!beginstate!" (
        sc %2 %1 >nul
        echo Trying to %2 service %1 ... >>"%LOG%"
    ) else if "%%i"=="!finalstate!" (
        set RETURN=TRUE
        goto :EOF
    ) else (
        echo Service %1 is in a pending state, script was aborted^^! >>"%LOG%"
        set RETURN=FALSE
        goto :EOF
    )
)
set /a SECONDS=0
:loopwait
for /f "tokens=3" %%i in ('sc query %1 ^| find "STATE"') do (
    if not "%%i"=="!finalstate!" (
        ping -n 1 localhost >nul
        set /a SECONDS+=1
        echo Process to %2 service %1 still in progress ... >>"%LOG%"
        if !SECONDS! EQU 10 (
            echo Process to %2 service %1 failed to terminate within 10 seconds, script was aborted^^! >>"%LOG%"
            set RETURN=FALSE
            goto :EOF
        ) else (
            goto loopwait
        )
    ) else (
        echo      ... terminated successfully. >>"%LOG%"
        set RETURN=TRUE
    )
)
goto :EOF

:end
ENDLOCAL

Safe and close dbx.cmd.

Then start the Windows Task Scheduler and create a new task:

On the General tab:

• Name it as you like, e.g. "DbxSvc-Workaround"
• Select a user with administative rights (Change User or Group)
• Select it to be executed independent from the User Login (Run whether user is logged on or not)
• Select (check the checkbox) "Run with highest privileges"

On the Trigger tab:

• Add a new trigger "On an event" and select the Protocol "Application", the Source "DbxSvc" and the Event-ID 320

On the Actions tab:

• Add a new action "Start a program" and specify the path: D:\CMD\dbx.cmd

All other settings can be left with their default values.

Note:

1. Once the problem is fixed, the task will never be scheduled anymore.
2. The task only consumes computing resources if triggered by the unwanted event. After the repair (via the script) it goes back to sleep.

Have fun!

<EDIT>

Did some code optimization - less code now due to use of functions.

In addition, the activities executed by the script are logged in a file dbx.log.

</EDIT>

Loopback

Kudos to people like you doing the job instead of dropbox.

Their ignorance is amazing.